blob: 540ecce79f7ea217597497873b8d669be9ab6797 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
@echo off
rem ***********************************************************
rem * ODE Windows Binary Release Script
rem * Originally written by Jason Perkins (starkos@gmail.com)
rem *
rem * See README.txt in this directory for complete release
rem * instructions before running this script.
rem *
rem * Prerequisites:
rem * Command-line svn installed on path
rem * Command-line 7z (7zip) installed on path
rem * Command-line doxygen installed on path
rem * Run from Visual Studio 2003 command prompt
rem ***********************************************************
rem * Check arguments
if "%1"=="" goto show_usage
rem ***********************************************************
rem * Pre-build checklist
rem ***********************************************************
echo.
echo STARTING PREBUILD CHECKLIST, PRESS ^^C TO ABORT.
echo.
echo Are you running at the VS2003 command prompt?
pause
echo.
echo Is the version number "%1" correct?
pause
echo.
echo Does the release branch "%1" exist in SVN?
pause
echo.
echo Are 'svn', '7z', and 'doxygen' on the path?
pause
echo.
echo Okay, ready to build the Windows binary packages for version %1!
pause
rem ***********************************************************
rem * Retrieve source code
rem ***********************************************************
echo.
echo RETRIEVING SOURCE CODE FROM REPOSITORY...
echo.
svn export https://opende.svn.sourceforge.net/svnroot/opende/branches/%1 ode-%1
rem ***********************************************************
rem * Prepare source code
rem ***********************************************************
echo.
echo PREPARING SOURCE TREE...
echo.
cd ode-%1
copy build\config-default.h include\ode\config.h
cd ode\doc
doxygen
cd ..\..\..
rem ***********************************************************
rem * Build the binaries
rem ***********************************************************
echo.
echo BUILDING RELEASE BINARIES (this will take a while)...
echo.
cd ode-%1\build\vs2003
devenv.exe ode.sln /build DebugLib /project ode
devenv.exe ode.sln /build DebugDLL /project ode
devenv.exe ode.sln /build ReleaseLib /project ode
devenv.exe ode.sln /build ReleaseDLL /project ode
rem ***********************************************************
rem * Package things up
rem ***********************************************************
cd ..\..
move lib\ReleaseDLL\ode.lib lib\ReleaseDLL\ode-imports.lib
cd ..
7z a -tzip ode-win32-%1.zip ode-%1\*.txt ode-%1\include\ode\*.h ode-%1\lib\* ode-%1\docs\*
rem ***********************************************************
rem * Clean up
rem ***********************************************************
echo.
echo CLEANING UP...
echo.
rmdir /s /q ode-%1
rem ***********************************************************
rem * Upload to SF.net
rem ***********************************************************
echo.
echo Ready to upload package to SourceForce, press ^^C to abort.
pause
echo "anonymous" > ftp.txt
echo "starkos" >> ftp.txt
echo "cd incoming" >> ftp.txt
echo "bin" >> ftp.txt
echo "put ode-win32-%1.zip" >> ftp.txt
echo "quit" >> ftp.txt
ftp -s:ftp.txt upload.sourceforge.net
erase ftp.txt
goto done
rem ***********************************************************
rem * Error messages
rem ***********************************************************
:show_usage
echo Usage: msw_release.bat version_number
goto done
:done
|
